Create OpenCL imported target

CMakeLists.txt

@@ -2099,8 +2099,6 @@ if(ENABLE_OPENCL)
     if(NOT OPENCL_FOUND)
         message(STATUS "Processing blocks using OpenCL will not be built.")
     endif()
-else()
-    set(OPENCL_FOUND FALSE)
 endif()
 
 

cmake/Modules/FindOPENCL.cmake

@@ -1,4 +1,4 @@
-# Copyright (C) 2011-2018 (see AUTHORS file for a list of contributors)
+# Copyright (C) 2011-2019 (see AUTHORS file for a list of contributors)
 #
 # This file is part of GNSS-SDR.
 #
@@ -20,7 +20,7 @@
 #
 # - Try to find OpenCL
 # This module tries to find an OpenCL implementation on your system. It supports
-# AMD / ATI, Apple and NVIDIA implementations, but shoudl work, too.
+# AMD / ATI, Apple and NVIDIA implementations.
 #
 # Once done this will define
 # OPENCL_FOUND - system has OpenCL
@@ -35,85 +35,189 @@ endif()
 
 include(FindPackageHandleStandardArgs)
 
-set(OPENCL_VERSION_STRING "0.1.0")
-set(OPENCL_VERSION_MAJOR 0)
-set(OPENCL_VERSION_MINOR 1)
-set(OPENCL_VERSION_PATCH 0)
+function(_FIND_OPENCL_VERSION)
+    include(CheckSymbolExists)
+    include(CMakePushCheckState)
+    set(CMAKE_REQUIRED_QUIET ${OPENCL_FIND_QUIETLY})
 
-if(APPLE)
-  find_library(OPENCL_LIBRARIES OpenCL DOC "OpenCL lib for OSX")
-  find_path(OPENCL_INCLUDE_DIRS OpenCL/cl.h DOC "Include for OpenCL on OSX")
-  find_path(_OPENCL_CPP_INCLUDE_DIRS OpenCL/cl.hpp DOC "Include for OpenCL CPP bindings on OSX")
+    cmake_push_check_state()
+    foreach(VERSION "2_2" "2_1" "2_0" "1_2" "1_1" "1_0")
+        set(CMAKE_REQUIRED_INCLUDES "${OPENCL_INCLUDE_DIR}")
 
-else()
-  if(WIN32)
-    find_path(OPENCL_INCLUDE_DIRS CL/cl.h)
-    find_path(_OPENCL_CPP_INCLUDE_DIRS CL/cl.hpp)
+        if(APPLE)
+            check_symbol_exists(
+                CL_VERSION_${VERSION}
+                "${OPENCL_INCLUDE_DIR}/Headers/cl.h"
+                OPENCL_VERSION_${VERSION}
+            )
+        else()
+            check_symbol_exists(
+                CL_VERSION_${VERSION}
+                "${OPENCL_INCLUDE_DIR}/CL/cl.h"
+                OPENCL_VERSION_${VERSION}
+            )
+        endif()
 
-    # The AMD SDK currently installs both x86 and x86_64 libraries
-    # This is only a hack to find out architecture
-    if(${CMAKE_SYSTEM_PROCESSOR} STREQUAL "AMD64")
-      set(OPENCL_LIB_DIR "$ENV{ATISTREAMSDKROOT}/lib/x86_64")
-      set(OPENCL_LIB_DIR "$ENV{ATIINTERNALSTREAMSDKROOT}/lib/x86_64")
-    else()
-      set(OPENCL_LIB_DIR "$ENV{ATISTREAMSDKROOT}/lib/x86")
-      set(OPENCL_LIB_DIR "$ENV{ATIINTERNALSTREAMSDKROOT}/lib/x86")
-    endif()
+        if(OPENCL_VERSION_${VERSION})
+            string(REPLACE "_" "." VERSION "${VERSION}")
+            set(OPENCL_VERSION_STRING ${VERSION} PARENT_SCOPE)
+            string(REGEX MATCHALL "[0-9]+" version_components "${VERSION}")
+            list(GET version_components 0 major_version)
+            list(GET version_components 1 minor_version)
+            set(OPENCL_VERSION_MAJOR ${major_version} PARENT_SCOPE)
+            set(OPENCL_VERSION_MINOR ${minor_version} PARENT_SCOPE)
+            break()
+        endif()
+    endforeach()
+    cmake_pop_check_state()
+endfunction()
 
-    # find out if the user asked for a 64-bit build, and use the corresponding
-    # 64 or 32 bit NVIDIA library paths to the search:
-    string(REGEX MATCH "Win64" ISWIN64 ${CMAKE_GENERATOR})
-    if("${ISWIN64}" STREQUAL "Win64")
-      find_library(OPENCL_LIBRARIES OpenCL.lib ${OPENCL_LIB_DIR} $ENV{CUDA_LIB_PATH} $ENV{CUDA_PATH}/lib/x64)
-    else()
-      find_library(OPENCL_LIBRARIES OpenCL.lib ${OPENCL_LIB_DIR} $ENV{CUDA_LIB_PATH} $ENV{CUDA_PATH}/lib/Win32)
-    endif()
+find_path(OPENCL_INCLUDE_DIR
+    NAMES
+        CL/cl.h OpenCL/cl.h
+    PATHS
+        ENV "PROGRAMFILES(X86)"
+        ENV AMDAPPSDKROOT
+        ENV INTELOCLSDKROOT
+        ENV NVSDKCOMPUTE_ROOT
+        ENV CUDA_PATH
+        ENV ATISTREAMSDKROOT
+        ENV OCL_ROOT
+        /usr/local/cuda/include
+    PATH_SUFFIXES
+        include
+        OpenCL/common/inc
+        "AMD APP/include"
+)
 
-    get_filename_component(_OPENCL_INC_CAND ${OPENCL_LIB_DIR}/../../include ABSOLUTE)
+find_path(_OPENCL_CPP_INCLUDE_DIRS
+    NAMES
+        CL/cl.hpp OpenCL/cl.hpp
+    PATHS
+        ENV "PROGRAMFILES(X86)"
+        ENV AMDAPPSDKROOT
+        ENV INTELOCLSDKROOT
+        ENV NVSDKCOMPUTE_ROOT
+        ENV CUDA_PATH
+        ENV ATISTREAMSDKROOT
+        ENV OCL_ROOT
+        /usr/local/cuda/include
+    PATH_SUFFIXES
+       include
+       OpenCL/common/inc
+       "AMD APP/include"
+)
 
-    # On Win32 search relative to the library
-    find_path(OPENCL_INCLUDE_DIRS CL/cl.h PATHS "${_OPENCL_INC_CAND}" $ENV{CUDA_INC_PATH} $ENV{CUDA_PATH}/include)
-    find_path(_OPENCL_CPP_INCLUDE_DIRS CL/cl.hpp PATHS "${_OPENCL_INC_CAND}" $ENV{CUDA_INC_PATH} $ENV{CUDA_PATH}/include)
-
-  else()
-    # Unix style platforms
-    find_library(OPENCL_LIBRARIES OpenCL
-      ENV LD_LIBRARY_PATH
-    )
-
-    get_filename_component(OPENCL_LIB_DIR ${OPENCL_LIBRARIES} PATH)
-    get_filename_component(_OPENCL_INC_CAND ${OPENCL_LIB_DIR}/../../include ABSOLUTE)
-
-    # The AMD SDK currently does not place its headers
-    # in /usr/include, therefore also search relative
-    # to the library
-    find_path(OPENCL_INCLUDE_DIRS CL/cl.h PATHS ${_OPENCL_INC_CAND} "/usr/local/cuda/include")
-    find_path(_OPENCL_CPP_INCLUDE_DIRS CL/cl.hpp PATHS ${_OPENCL_INC_CAND} "/usr/local/cuda/include")
-  endif()
+set(OPENCL_INCLUDE_DIRS ${OPENCL_INCLUDE_DIR})
+if(_OPENCL_CPP_INCLUDE_DIRS)
+    set(OPENCL_HAS_CPP_BINDINGS TRUE)
+    list(APPEND OPENCL_INCLUDE_DIRS ${_OPENCL_CPP_INCLUDE_DIRS})
+    # This is often the same, so clean up
+    list(REMOVE_DUPLICATES OPENCL_INCLUDE_DIRS)
 endif()
 
+_FIND_OPENCL_VERSION()
+
+if(WIN32)
+    if(CMAKE_SIZEOF_VOID_P EQUAL 4)
+        find_library(OPENCL_LIBRARY
+            NAMES OpenCL
+            PATHS
+                ENV "PROGRAMFILES(X86)"
+                ENV AMDAPPSDKROOT
+                ENV INTELOCLSDKROOT
+                ENV CUDA_PATH
+                ENV NVSDKCOMPUTE_ROOT
+                ENV ATISTREAMSDKROOT
+                ENV OCL_ROOT
+            PATH_SUFFIXES
+                "AMD APP/lib/x86"
+                lib/x86
+                lib/Win32
+                OpenCL/common/lib/Win32
+        )
+    elseif(CMAKE_SIZEOF_VOID_P EQUAL 8)
+        find_library(OPENCL_LIBRARY
+            NAMES OpenCL
+            PATHS
+                ENV "PROGRAMFILES(X86)"
+                ENV AMDAPPSDKROOT
+                ENV INTELOCLSDKROOT
+                ENV CUDA_PATH
+                ENV NVSDKCOMPUTE_ROOT
+                ENV ATISTREAMSDKROOT
+                ENV OCL_ROOT
+            PATH_SUFFIXES
+                "AMD APP/lib/x86_64"
+                lib/x86_64
+                lib/x64
+                OpenCL/common/lib/x64
+        )
+    endif()
+else()
+    if(CMAKE_SIZEOF_VOID_P EQUAL 4)
+        find_library(OPENCL_LIBRARY
+            NAMES OpenCL
+            PATHS
+                ENV AMDAPPSDKROOT
+                ENV CUDA_PATH
+                ENV LD_LIBRARY_PATH
+            PATH_SUFFIXES
+                lib/x86
+                lib
+        )
+    elseif(CMAKE_SIZEOF_VOID_P EQUAL 8)
+        find_library(OPENCL_LIBRARY
+            NAMES OpenCL
+            PATHS
+                ENV AMDAPPSDKROOT
+                ENV CUDA_PATH
+                ENV LD_LIBRARY_PATH
+            PATH_SUFFIXES
+                lib/x86_64
+                lib/x64
+                lib
+                lib64
+        )
+    endif()
+endif()
+
+set(OPENCL_LIBRARIES ${OPENCL_LIBRARY})
+
 find_package_handle_standard_args(OPENCL DEFAULT_MSG OPENCL_LIBRARIES OPENCL_INCLUDE_DIRS)
 
-if(_OPENCL_CPP_INCLUDE_DIRS)
-  set(OPENCL_HAS_CPP_BINDINGS TRUE)
-  list(APPEND OPENCL_INCLUDE_DIRS ${_OPENCL_CPP_INCLUDE_DIRS})
-  # This is often the same, so clean up
-  list(REMOVE_DUPLICATES OPENCL_INCLUDE_DIRS)
-endif()
-
 mark_as_advanced(
   OPENCL_INCLUDE_DIRS
+  OPENCL_LIBRARIES
 )
 
 set_package_properties(OPENCL PROPERTIES
     URL "https://www.khronos.org/opencl/"
-    DESCRIPTION "Library for parallel programming"
 )
 
-if(OPENCL_INCLUDE_DIRS AND OPENCL_LIBRARIES)
-    set( OPENCL_FOUND TRUE )
-    add_definitions( -DOPENCL=1 )
+if(OPENCL_FOUND AND OPENCL_VERSION_STRING)
+    set_package_properties(OPENCL PROPERTIES
+        DESCRIPTION "Library for parallel programming (found: v${OPENCL_VERSION_STRING})"
+    )
 else()
-    set( OPENCL_FOUND FALSE )
-    add_definitions( -DOPENCL=0 )
+    set_package_properties(OPENCL PROPERTIES
+        DESCRIPTION "Library for parallel programming"
+    )
+endif()
+
+if(OPENCL_FOUND AND NOT TARGET OpenCL::OpenCL)
+    if(OPENCL_LIBRARY MATCHES "/([^/]+)\\.framework$")
+        add_library(OpenCL::OpenCL INTERFACE IMPORTED)
+        set_target_properties(OpenCL::OpenCL PROPERTIES
+            INTERFACE_LINK_LIBRARIES "${OPENCL_LIBRARY}"
+        )
+    else()
+        add_library(OpenCL::OpenCL UNKNOWN IMPORTED)
+        set_target_properties(OpenCL::OpenCL PROPERTIES
+            IMPORTED_LOCATION "${OPENCL_LIBRARY}"
+        )
+    endif()
+    set_target_properties(OpenCL::OpenCL PROPERTIES
+        INTERFACE_INCLUDE_DIRECTORIES "${OPENCL_INCLUDE_DIRS}"
+    )
 endif()

src/algorithms/acquisition/gnuradio_blocks/CMakeLists.txt

@@ -49,16 +49,6 @@ if(OPENCL_FOUND)
     set(ACQ_GR_BLOCKS_HEADERS ${ACQ_GR_BLOCKS_HEADERS} pcps_opencl_acquisition_cc.h)
 endif()
 
-
-if(OPENCL_FOUND)
-    include_directories(${OPENCL_INCLUDE_DIRS})
-    if(OS_IS_MACOSX)
-        set(OPT_LIBRARIES ${OPT_LIBRARIES} "-framework OpenCL")
-    else()
-        set(OPT_LIBRARIES ${OPT_LIBRARIES} ${OPENCL_LIBRARIES})
-    endif()
-endif()
-
 list(SORT ACQ_GR_BLOCKS_HEADERS)
 list(SORT ACQ_GR_BLOCKS_SOURCES)
 
@@ -84,7 +74,6 @@ target_link_libraries(acquisition_gr_blocks
         channel_libs
         acquisition_libs
         core_system_parameters
-        ${OPT_LIBRARIES}
     PRIVATE
         Gflags::gflags
         Glog::glog
@@ -101,7 +90,7 @@ target_include_directories(acquisition_gr_blocks
 )
 
 if(OPENCL_FOUND)
-    target_include_directories(acquisition_gr_blocks PUBLIC ${OPENCL_INCLUDE_DIRS})
+    target_link_libraries(acquisition_gr_blocks PUBLIC OpenCL::OpenCL)
 endif()
 
 if(ENABLE_CLANG_TIDY)

src/algorithms/acquisition/gnuradio_blocks/pcps_opencl_acquisition_cc.h

@@ -63,6 +63,7 @@
 #include <vector>
 
 #ifdef __APPLE__
+#define CL_SILENCE_DEPRECATION
 #include "opencl/cl.hpp"
 #else
 #include <CL/cl.hpp>

src/algorithms/libs/CMakeLists.txt

@@ -73,12 +73,6 @@ if(OPENCL_FOUND)
         opencl/fft_setup.cc # Needs OpenCL
         opencl/fft_kernelstring.cc # Needs OpenCL
     )
-    include_directories(${OPENCL_INCLUDE_DIRS})
-    if(OS_IS_MACOSX)
-        set(OPT_LIBRARIES ${OPT_LIBRARIES} "-framework OpenCL")
-    else()
-        set(OPT_LIBRARIES ${OPT_LIBRARIES} ${OPENCL_LIBRARIES})
-    endif()
 endif()
 
 list(SORT GNSS_SPLIBS_HEADERS)
@@ -105,7 +99,6 @@ target_link_libraries(algorithms_libs
         Gflags::gflags
         Gnuradio::runtime
         Gnuradio::blocks
-        ${OPT_LIBRARIES}
     PRIVATE
         core_system_parameters
         Volk::volk ${ORC_LIBRARIES}
@@ -113,6 +106,13 @@ target_link_libraries(algorithms_libs
         Glog::glog
 )
 
+if(OPENCL_FOUND)
+    target_link_libraries(algorithms_libs PUBLIC OpenCL::OpenCL)
+    target_include_directories(algorithms_libs PUBLIC
+        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/opencl
+    )
+endif()
+
 target_include_directories(algorithms_libs
     PUBLIC
         ${CMAKE_SOURCE_DIR}/src/core/interfaces
@@ -145,7 +145,7 @@ add_library(gnss_sdr_flags gnss_sdr_flags.cc gnss_sdr_flags.h)
 if(${FILESYSTEM_FOUND})
     target_compile_definitions(gnss_sdr_flags PRIVATE -DHAS_STD_FILESYSTEM=1)
     if(${find_experimental})
-        add_definitions(-DHAS_STD_FILESYSTEM_EXPERIMENTAL=1)
+        target_compile_definitions(gnss_sdr_flags PRIVATE -DHAS_STD_FILESYSTEM_EXPERIMENTAL=1)
     endif()
     target_link_libraries(gnss_sdr_flags PRIVATE std::filesystem)
 else()

src/algorithms/libs/opencl/clFFT.h

@@ -57,6 +57,7 @@ extern "C"
 #include <stdio.h>
 
 #ifdef __APPLE__
+#define CL_SILENCE_DEPRECATION
 #include <OpenCL/opencl.h>
 #else
 #include <CL/cl.h>