mirror of
https://github.com/gnss-sdr/gnss-sdr
synced 2024-09-27 06:38:23 +00:00
f0e1ef6f9a
Makes transition to GNU Radio 3.9 API less verbose
131 lines
3.0 KiB
CMake
131 lines
3.0 KiB
CMake
# Copyright (C) 2012-2020 (see AUTHORS file for a list of contributors)
|
|
#
|
|
# GNSS-SDR is a software-defined Global Navigation Satellite Systems receiver
|
|
#
|
|
# This file is part of GNSS-SDR.
|
|
#
|
|
# SPDX-License-Identifier: GPL-3.0-or-later
|
|
#
|
|
|
|
add_subdirectory(supl)
|
|
|
|
set(CORE_LIBS_SOURCES
|
|
ini.cc
|
|
INIReader.cc
|
|
string_converter.cc
|
|
gnss_sdr_supl_client.cc
|
|
gnss_sdr_sample_counter.cc
|
|
channel_status_msg_receiver.cc
|
|
channel_event.cc
|
|
command_event.cc
|
|
)
|
|
|
|
set(CORE_LIBS_HEADERS
|
|
ini.h
|
|
INIReader.h
|
|
string_converter.h
|
|
gnss_sdr_supl_client.h
|
|
gnss_sdr_sample_counter.h
|
|
channel_status_msg_receiver.h
|
|
channel_event.h
|
|
command_event.h
|
|
)
|
|
|
|
if(ENABLE_FPGA)
|
|
set(CORE_LIBS_SOURCES
|
|
${CORE_LIBS_SOURCES}
|
|
gnss_sdr_fpga_sample_counter.cc
|
|
gnss_sdr_time_counter.cc
|
|
)
|
|
set(CORE_LIBS_HEADERS
|
|
${CORE_LIBS_HEADERS}
|
|
gnss_sdr_fpga_sample_counter.h
|
|
gnss_sdr_time_counter.h
|
|
)
|
|
endif()
|
|
|
|
list(SORT CORE_LIBS_HEADERS)
|
|
list(SORT CORE_LIBS_SOURCES)
|
|
|
|
if(USE_CMAKE_TARGET_SOURCES)
|
|
add_library(core_libs STATIC)
|
|
target_sources(core_libs
|
|
PRIVATE
|
|
${CORE_LIBS_SOURCES}
|
|
PUBLIC
|
|
${CORE_LIBS_HEADERS}
|
|
)
|
|
else()
|
|
source_group(Headers FILES ${CORE_LIBS_HEADERS})
|
|
add_library(core_libs ${CORE_LIBS_SOURCES} ${CORE_LIBS_HEADERS})
|
|
endif()
|
|
|
|
target_link_libraries(core_libs
|
|
PUBLIC
|
|
Gnuradio::blocks
|
|
Gnuradio::runtime
|
|
Gnuradio::pmt
|
|
core_libs_supl
|
|
core_system_parameters
|
|
pvt_libs
|
|
PRIVATE
|
|
Boost::serialization
|
|
Gflags::gflags
|
|
Glog::glog
|
|
Pugixml::pugixml
|
|
)
|
|
|
|
if(USE_GENERIC_LAMBDAS AND NOT GNURADIO_USES_STD_POINTERS)
|
|
target_link_libraries(core_libs PUBLIC Boost::headers)
|
|
else()
|
|
target_link_libraries(core_libs PRIVATE Boost::headers)
|
|
endif()
|
|
|
|
if(GNURADIO_USES_STD_POINTERS)
|
|
target_compile_definitions(core_libs
|
|
PUBLIC -DGNURADIO_USES_STD_POINTERS=1
|
|
)
|
|
endif()
|
|
|
|
target_include_directories(core_libs
|
|
PUBLIC
|
|
${CMAKE_SOURCE_DIR}/src/core/interfaces
|
|
)
|
|
|
|
if(USE_GENERIC_LAMBDAS)
|
|
set(has_generic_lambdas HAS_GENERIC_LAMBDA=1)
|
|
set(no_has_generic_lambdas HAS_GENERIC_LAMBDA=0)
|
|
target_compile_definitions(core_libs
|
|
PRIVATE
|
|
"$<$<COMPILE_FEATURES:cxx_generic_lambdas>:${has_generic_lambdas}>"
|
|
"$<$<NOT:$<COMPILE_FEATURES:cxx_generic_lambdas>>:${no_has_generic_lambdas}>"
|
|
)
|
|
else()
|
|
target_compile_definitions(core_libs
|
|
PRIVATE
|
|
-DHAS_GENERIC_LAMBDA=0
|
|
)
|
|
endif()
|
|
|
|
if(USE_BOOST_BIND_PLACEHOLDERS)
|
|
target_compile_definitions(core_libs
|
|
PRIVATE
|
|
-DUSE_BOOST_BIND_PLACEHOLDERS=1
|
|
)
|
|
endif()
|
|
|
|
if(ENABLE_CLANG_TIDY)
|
|
if(CLANG_TIDY_EXE)
|
|
set_target_properties(core_libs
|
|
PROPERTIES
|
|
CXX_CLANG_TIDY "${DO_CLANG_TIDY}"
|
|
)
|
|
endif()
|
|
endif()
|
|
|
|
set_property(TARGET core_libs
|
|
APPEND PROPERTY INTERFACE_INCLUDE_DIRECTORIES
|
|
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
|
|
$<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/src/core/interfaces>
|
|
)
|