mirror of
https://github.com/SquidDev-CC/CC-Tweaked
synced 2024-12-14 20:20:30 +00:00
87c6d3aef6
- Remove deprecated API members in prep for 1.19.3. This allows us to remove the mc-stubs and forge-stubs projects. - Make several methods take a MinecraftServer instead of a Level (or nothing at all). - Remove I prefixes from a whole bunch of interfaces, making things a little more consistent with Java conventions. This avoids touching the "main" interfaces people consume for now. I want to do that another Minecraft version, to avoid making the update too painful. - Remove IFileSystem and associated getters. This has never worked very well and I don't think has got much (any?) usage.
67 lines
1.6 KiB
Plaintext
67 lines
1.6 KiB
Plaintext
pluginManagement {
|
|
// Duplicated in buildSrc/build.gradle.kts
|
|
repositories {
|
|
mavenCentral()
|
|
gradlePluginPortal()
|
|
|
|
maven("https://maven.minecraftforge.net") {
|
|
name = "Forge"
|
|
content {
|
|
includeGroup("net.minecraftforge")
|
|
includeGroup("net.minecraftforge.gradle")
|
|
}
|
|
}
|
|
|
|
maven("https://maven.parchmentmc.org") {
|
|
name = "Librarian"
|
|
content {
|
|
includeGroupByRegex("^org\\.parchmentmc.*")
|
|
}
|
|
}
|
|
|
|
maven("https://repo.spongepowered.org/repository/maven-public/") {
|
|
name = "Sponge"
|
|
content {
|
|
includeGroup("org.spongepowered")
|
|
includeGroup("org.spongepowered.gradle.vanilla")
|
|
}
|
|
}
|
|
|
|
maven("https://maven.fabricmc.net/") {
|
|
name = "Fabric"
|
|
content {
|
|
includeGroup("fabric-loom")
|
|
includeGroup("net.fabricmc")
|
|
}
|
|
}
|
|
}
|
|
|
|
resolutionStrategy {
|
|
eachPlugin {
|
|
if (requested.id.id == "org.spongepowered.mixin") {
|
|
useModule("org.spongepowered:mixingradle:${requested.version}")
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
val mcVersion: String by settings
|
|
rootProject.name = "cc-tweaked-$mcVersion"
|
|
|
|
include(":core-api")
|
|
include(":core")
|
|
|
|
include(":common-api")
|
|
include(":common")
|
|
include(":fabric-api")
|
|
include(":fabric")
|
|
include(":forge-api")
|
|
include(":forge")
|
|
|
|
include(":lints")
|
|
include(":web")
|
|
|
|
for (project in rootProject.children) {
|
|
project.projectDir = file("projects/${project.name}")
|
|
}
|