// SPDX-FileCopyrightText: 2022 The CC: Tweaked Developers
//
// SPDX-License-Identifier: MPL-2.0

plugins {
    `java-gradle-plugin`
    `kotlin-dsl`
    alias(libs.plugins.gradleVersions)
    alias(libs.plugins.versionCatalogUpdate)
}

// Duplicated in settings.gradle.kts
repositories {
    mavenCentral()
    gradlePluginPortal()

    maven("https://maven.neoforged.net/releases") {
        name = "NeoForge"
        content {
            includeGroup("net.minecraftforge")
            includeGroup("net.neoforged")
            includeGroup("net.neoforged.gradle")
            includeModule("codechicken", "DiffPatch")
            includeModule("net.covers1624", "Quack")
        }
    }

    maven("https://maven.fabricmc.net/") {
        name = "Fabric"
        content {
            includeGroup("net.fabricmc")
        }
    }

    maven("https://squiddev.cc/maven") {
        name = "SquidDev"
        content {
            includeGroup("cc.tweaked.vanilla-extract")
        }
    }
}

dependencies {
    implementation(libs.errorProne.plugin)
    implementation(libs.kotlin.plugin)
    implementation(libs.spotless)

    implementation(libs.curseForgeGradle)
    implementation(libs.fabric.loom)
    implementation(libs.ideaExt)
    implementation(libs.minotaur)
    implementation(libs.neoGradle.userdev)
    implementation(libs.vanillaExtract)
}

gradlePlugin {
    plugins {
        register("cc-tweaked") {
            id = "cc-tweaked"
            implementationClass = "cc.tweaked.gradle.CCTweakedPlugin"
        }

        register("cc-tweaked.illuaminate") {
            id = "cc-tweaked.illuaminate"
            implementationClass = "cc.tweaked.gradle.IlluaminatePlugin"
        }

        register("cc-tweaked.node") {
            id = "cc-tweaked.node"
            implementationClass = "cc.tweaked.gradle.NodePlugin"
        }
    }
}

versionCatalogUpdate {
    sortByKey.set(false)
    keep { keepUnusedLibraries.set(true) }
    catalogFile.set(file("../gradle/libs.versions.toml"))
}